# Maintainer: Tobias Reisinger <tobias@msrg.cc>
pkgname=emgauwa-core-testing
pkgver=0.4.3
pkgrel=1
epoch=
pkgdesc=""
arch=('x86_64' 'armv6h'  'armv7h' 'aarch64')
url="https://git.serguzim.me/emgauwa/core"
license=('unknown')
groups=()
depends=('sqlite')
makedepends=('make' 'cmake' 'gcc' 'vim')
conflicts=('emgauwa-core')
backup=('etc/emgauwa/core.conf')
source=("https://git.serguzim.me/emgauwa/core/archive/testing-v$pkgver.tar.gz"
        "core.conf"
        "emgauwa-core-testing.service"
        "emgauwa-core-testing.sysusers"
        "emgauwa-core-testing.tmpfiles")
sha256sums=('88faa22ab02050d26670bd783e1383191ee9ab7ed2dca357253828b230ece90e'
            'ac9cb03e0aee8cc7253f25f6c950936fb8195e450d38c2b369325038d3294d93'
            '541f0c83d883416eec015b5d47061c221ba2aa1ea5683b78a0aaa32145b955e3'
            'b9cde58b9e9b0605ca4a1eddd78067c55aa3c8d40f80cde0a25c4da9f6f95798'
            '6ba73fc7f6eed099697db53bc68e65d7592bd761933b580996f801070cbc809c')

prepare() {
    cd "core"
    mkdir -p "build"
}

build() {
    cd "core/build" || exit 1
    cmake ..
    make
}

package() {
    install -Dm755 "core/build/core"            "${pkgdir}/usr/bin/emgauwa-core"

    install -Ddm750                             "${pkgdir}/etc/emgauwa/"
    install -Ddm750                             "${pkgdir}/etc/emgauwa/core.conf.d/"

    install -Dm660 "core.conf"                  "${pkgdir}/etc/emgauwa/core.conf"

    install -Ddm750                             "${pkgdir}/var/lib/emgauwa"
    install -Ddm750                             "${pkgdir}/var/lib/emgauwa/core/"

    install -Dm644 "${pkgname}.service"         "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
    install -Dm644 "${pkgname}.tmpfiles"        "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
    install -Dm644 "${pkgname}.sysusers"        "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
}