# Maintainer: Tobias Reisinger <tobias@msrg.cc>
pkgname=emgauwa-controller-testing
pkgver=0.4.0
pkgrel=1
epoch=
pkgdesc=""
arch=('x86_64' 'armv6h'  'armv7h' 'aarch64')
url="https://git.serguzim.me/emgauwa/controller"
license=('unknown')
groups=()
depends=('glibc' 'lmdb')
depends_armv6h=('wiringpi')
depends_armv7h=('wiringpi')
makedepends=('make' 'cmake' 'gcc')
conflicts=('emgauwa-controller')
backup=('etc/emgauwa/controller.conf'
        'etc/emgauwa/controller2.conf')
source=("https://git.serguzim.me/emgauwa/controller/archive/testing-v$pkgver.tar.gz"
        "controller.conf"
        "controller2.conf"
        "emgauwa-controller-testing.service"
        "emgauwa-controller-testing2.service"
        "emgauwa-controller-testing.sysusers"
        "emgauwa-controller-testing.tmpfiles")
sha256sums=('9bc85905e83ad31cc8b8f72245c8e3470fef4309b4dc47ffe4588211e306c3f3'
            '48463574063a4224cc1aaeb4725deaa12789fe1797b7647fd57949bf8b3e3ef0'
            '4030e025022e94b328ab38fbf43c7f88b87376cb45bd6f32de14333ff27bb676'
            '0b61a8de493e1aef4e00575710b5874f1e8b07c919d298bb0474355236fb76c7'
            'c539ba0bd5b51f1896e2215d205a75ca31f50ecd636ee77c8671c4f19d319897'
            'b9cde58b9e9b0605ca4a1eddd78067c55aa3c8d40f80cde0a25c4da9f6f95798'
            '81f3872318a669e21a8a7b31c97fa3e14dc10f8aed1df74fb983b417ba74be89')

prepare() {
    cd "controller"
    mkdir -p "build"
}

build() {
    cd "controller/build" || exit 1
    cmake -DWIRING_PI_DEBUG=ON ..
    make
}

package() {
    install -Dm755 "controller/build/controller"    "${pkgdir}/usr/bin/emgauwa-controller"

    install -Dm660 "controller.conf"                 "${pkgdir}/etc/emgauwa/controller.conf"
    install -Dm660 "controller2.conf"                "${pkgdir}/etc/emgauwa/controller2.conf"
    install -Dm644 "${pkgname}.service"             "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
    install -Dm644 "${pkgname}2.service"            "${pkgdir}/usr/lib/systemd/system/${pkgname}2.service"
    install -Dm644 "${pkgname}.tmpfiles"            "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
    install -Dm644 "${pkgname}.sysusers"            "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
    
    install -Ddm750                                 "${pkgdir}/var/lib/emgauwa"
    install -Ddm750                                 "${pkgdir}/var/lib/emgauwa/controller"
}