# Maintainer: Tobias Reisinger <tobias@msrg.cc>
pkgname=emgauwa-core-testing
pkgver=0.2.1
pkgrel=1
epoch=
pkgdesc=""
arch=('any')
url="https://git.serguzim.me/emgauwa/core"
license=('unknown')
groups=()
depends=('glibc' 'sqlite')
makedepends=('make' 'cmake' 'gcc')
conflicts=('emgauwa-core')
backup=('etc/emgauwa/core.ini')
source=("$pkgname-$pkgver.tar.gz::https://ci.serguzim.me/archive/emgauwa-core-testing/working/$pkgname.tar.gz"
        "core.ini"
        "emgauwa-core-testing.service"
        "emgauwa-core-testing.sysusers"
        "emgauwa-core-testing.tmpfiles")
sha256sums=("SKIP"
            "6f113aa1c6ddbf982674ee192db2462758f83dfff12ab85ed4e221c0fdcf7de8"
            "c781f4d50da8e158551a47a8549981dad05faaf2d632c4fde8b36b48474ab0ec"
            "b9cde58b9e9b0605ca4a1eddd78067c55aa3c8d40f80cde0a25c4da9f6f95798"
            "0531f10303410afd7e53099e66b124ef2fd14afec9d33c4a0146793375acb6c2")

pkgver() {
    grep -Po "^ *VERSION \K[[:digit:]]+\.[[:digit:]]+\.[[:digit:]]+$" "${pkgname}/CMakeLists.txt"
}

prepare() {
    cd "$pkgname"
    mkdir -p "build"
}

build() {
    cd "$pkgname/build" || exit 1
    cmake ..
    make
}

package() {
    install -Dm755 "${pkgname}/build/core"      "${pkgdir}/usr/bin/emgauwa-core"

    install -Dm600 "core.ini"                   "${pkgdir}/etc/emgauwa/core.ini"
    install -Dm644 "${pkgname}.service"         "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
    install -Dm644 "${pkgname}.tmpfiles"        "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
    install -Dm644 "${pkgname}.sysusers"        "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
    
    install -Ddm750                             "${pkgdir}/var/lib/emgauwa"
    install -Ddm750                             "${pkgdir}/var/lib/emgauwa/core"
}