# Maintainer: Tobias Reisinger <tobias@msrg.cc>
pkgname=emgauwa-controller-testing
pkgver=0.3.7
pkgrel=2
epoch=
pkgdesc=""
arch=('x86_64' 'armv6h'  'armv7h' 'aarch64')
url="https://git.serguzim.me/emgauwa/controller"
license=('unknown')
groups=()
depends=('glibc' 'lmdb')
depends_armv6h=('wiringpi')
depends_armv7h=('wiringpi')
makedepends=('make' 'cmake' 'gcc')
conflicts=('emgauwa-controller')
backup=('etc/emgauwa/controller.ini')
source=("https://git.serguzim.me/emgauwa/controller/archive/testing-v$pkgver.tar.gz"
        "controller.ini"
        "controller2.ini"
        "emgauwa-controller-testing.service"
        "emgauwa-controller-testing2.service"
        "emgauwa-controller-testing.sysusers"
        "emgauwa-controller-testing.tmpfiles")
sha256sums=('569acded9108ebf0e8c8fc5dcd0b27e8872d63b5cdf07b3e960f97bd996e8827'
            '16c4fb3323a6d74657c6fd57720406547a89e7fc0af5441ab2d155829a818541'
            'b91003f435b89726b7d578a55f53aa49d344a13118306e61911637f72eb22959'
            '0bbc44d680be2011800c553ae863663148be0820f08349993578c88e9a23b143'
            '6cd1f42a50e6023566120416309d46f89238f47c4f9bda9332510251ccaf7d5d'
            'b9cde58b9e9b0605ca4a1eddd78067c55aa3c8d40f80cde0a25c4da9f6f95798'
            '81f3872318a669e21a8a7b31c97fa3e14dc10f8aed1df74fb983b417ba74be89')

prepare() {
    cd "controller"
    mkdir -p "build"
}

build() {
    cd "controller/build" || exit 1
    cmake -DWIRING_PI_DEBUG=ON ..
    make
}

package() {
    install -Dm755 "controller/build/controller"    "${pkgdir}/usr/bin/emgauwa-controller"

    install -Dm660 "controller.ini"                 "${pkgdir}/etc/emgauwa/controller.ini"
    install -Dm660 "controller2.ini"                "${pkgdir}/etc/emgauwa/controller2.ini"
    install -Dm644 "${pkgname}.service"             "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
    install -Dm644 "${pkgname}2.service"            "${pkgdir}/usr/lib/systemd/system/${pkgname}2.service"
    install -Dm644 "${pkgname}.tmpfiles"            "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
    install -Dm644 "${pkgname}.sysusers"            "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
    
    install -Ddm750                                 "${pkgdir}/var/lib/emgauwa"
    install -Ddm750                                 "${pkgdir}/var/lib/emgauwa/controller"
}