# Maintainer: Tobias Reisinger <tobias@msrg.cc>
pkgname=emgauwa-controller-testing
pkgver=0.2.1
pkgrel=2
epoch=
pkgdesc=""
arch=('any')
url="https://git.serguzim.me/emgauwa/controller"
license=('unknown')
groups=()
depends=('glibc' 'lmdb')
makedepends=('make' 'cmake' 'gcc')
conflicts=('emgauwa-controller')
backup=('etc/emgauwa/controller.ini')
source=("$pkgname-$pkgver.tar.gz::https://ci.serguzim.me/archive/emgauwa-controller-testing/working/$pkgname.tar.gz"
        "controller.ini"
        "emgauwa-controller-testing.service"
        "emgauwa-controller-testing.sysusers"
        "emgauwa-controller-testing.tmpfiles")
sha256sums=("SKIP"
            "e467db2a2b382f34c125d01c735eb4ea83b971eb0928ac2863d19b7c151301c0"
            "0bbc44d680be2011800c553ae863663148be0820f08349993578c88e9a23b143"
            "b9cde58b9e9b0605ca4a1eddd78067c55aa3c8d40f80cde0a25c4da9f6f95798"
            "5a4ce46c1302546509c0024d4614b5b0d47dde02467b7bf52b28ef6c4ead91e7")

pkgver() {
    grep -Po "^ *VERSION \K[[:digit:]]+\.[[:digit:]]+\.[[:digit:]]+$" "${pkgname}/CMakeLists.txt"
}

prepare() {
    cd "$pkgname"
    mkdir -p "build"
}

build() {
    cd "$pkgname/build" || exit 1
    cmake -DWIRING_PI_DEBUG=ON ..
    make
}

package() {
    install -Dm755 "${pkgname}/build/controller"    "${pkgdir}/usr/bin/emgauwa-controller"

    install -Dm660 "controller.ini"                 "${pkgdir}/etc/emgauwa/controller.ini"
    install -Dm644 "${pkgname}.service"             "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
    install -Dm644 "${pkgname}.tmpfiles"            "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
    install -Dm644 "${pkgname}.sysusers"            "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
    
    install -Ddm750                                 "${pkgdir}/var/lib/emgauwa"
    install -Ddm750                                 "${pkgdir}/var/lib/emgauwa/controller"
}