package/controller-testing/PKGBUILD

# Maintainer: Tobias Reisinger <tobias@msrg.cc>
pkgname=emgauwa-controller-testing
pkgver=0.2.7
pkgrel=2
epoch=
pkgdesc=""
arch=('x86_64' 'armv6h'  'armv7h' 'aarch64')
url="https://git.serguzim.me/emgauwa/controller"
license=('unknown')
groups=()
depends=('glibc' 'lmdb')
depends_armv6h=('wiringpi')
depends_armv7h=('wiringpi')
makedepends=('make' 'cmake' 'gcc')
conflicts=('emgauwa-controller')
backup=('etc/emgauwa/controller.ini')
source=("https://git.serguzim.me/emgauwa/controller/archive/testing-v$pkgver.tar.gz"
        "controller.ini"
        "emgauwa-controller-testing.service"
        "emgauwa-controller-testing.sysusers"
        "emgauwa-controller-testing.tmpfiles")
sha256sums=('cf31625b779cbb21fd6d5452b0422e5351a42e42070dbc07b9ac388c2a090b90'
            'cfbf05b5e3045c9aad3979f366bdda6c5ca7d47e1bb4ad3bf855a39b99e88417'
            '0bbc44d680be2011800c553ae863663148be0820f08349993578c88e9a23b143'
            'b9cde58b9e9b0605ca4a1eddd78067c55aa3c8d40f80cde0a25c4da9f6f95798'
            'e62f47b41f0c4f116007ca0e05e0a50b45446763ccfa91b946b9d451c83ff5b4')

prepare() {
    cd "controller"
    mkdir -p "build"
}

build() {
    cd "controller/build" || exit 1
    cmake -DWIRING_PI_DEBUG=ON ..
    make
}

package() {
    install -Dm755 "controller/build/controller"    "${pkgdir}/usr/bin/emgauwa-controller"

    install -Dm660 "controller.ini"                 "${pkgdir}/etc/emgauwa/controller.ini"
    install -Dm644 "${pkgname}.service"             "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
    install -Dm644 "${pkgname}.tmpfiles"            "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
    install -Dm644 "${pkgname}.sysusers"            "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
    
    install -Ddm750                                 "${pkgdir}/var/lib/emgauwa"
    install -Ddm750                                 "${pkgdir}/var/lib/emgauwa/controller"
}