package/controller/PKGBUILD

# Maintainer: Tobias Reisinger <tobias@msrg.cc>
pkgname=emgauwa-controller
pkgver=0.3.2
pkgrel=2
epoch=
pkgdesc=""
arch=('x86_64' 'armv6h'  'armv7h' 'aarch64')
url="https://git.serguzim.me/emgauwa/controller"
license=('unknown')
groups=()
depends=('glibc' 'lmdb')
depends_armv6h=('wiringpi')
depends_armv7h=('wiringpi')
makedepends=('make' 'cmake' 'gcc')
conflicts=('emgauwa-controller-testing')
backup=('etc/emgauwa/controller.ini')
source=("https://git.serguzim.me/emgauwa/controller/archive/v$pkgver.tar.gz"
        "controller.ini"
        "emgauwa-controller.service"
        "emgauwa-controller.sysusers"
        "emgauwa-controller.tmpfiles")
sha256sums=('2ce6db4c299cc4064fa2d6a038462e07ad821a59071f7471865d750b6b4c94ea'
            'ecfd6167e75a8fbbeb619ce99dbd9263d321443b335d985d25cb303bb0ef61db'
            '8ece4b409d5550cdae23591217e440d8599ebf2175f2a91574c0b069314879a0'
            'b9cde58b9e9b0605ca4a1eddd78067c55aa3c8d40f80cde0a25c4da9f6f95798'
            'e62f47b41f0c4f116007ca0e05e0a50b45446763ccfa91b946b9d451c83ff5b4')

prepare() {
    cd "controller"
    mkdir -p "build"
}

build() {
    cd "controller/build" || exit 1
    cmake ..
    make
}

package() {
    install -Dm755 "controller/build/controller"    "${pkgdir}/usr/bin/emgauwa-controller"

    install -Dm660 "controller.ini"                 "${pkgdir}/etc/emgauwa/controller.ini"
    install -Dm644 "${pkgname}.service"             "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
    install -Dm644 "${pkgname}.tmpfiles"            "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
    install -Dm644 "${pkgname}.sysusers"            "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
    
    install -Ddm750                                 "${pkgdir}/var/lib/emgauwa"
    install -Ddm750                                 "${pkgdir}/var/lib/emgauwa/controller"
}